# **/\*The SAS program (HEI-2010 Individual Scores per day using ASA24-2011-14 data)**

# **PerDay.SAS\*/**

/\*This SAS program can be used to calculate Healthy Eating Index (HEI)-2010 scores from 24-hour recall data collected using ASA24-2011, ASA24-Kids-2013, ASA24-2014 and ASA24-Kids-2014. This program calculates HEI-2010 component and total scores for each recall (i.e., each individual's reported 1-day intake). \*/

/\*This program has been tested using SAS, version 9.2 and uses the INFMYPHEI and TNMYPHEI analysis files from ASA24. These files can be downloaded from the ASA24 Researcher website page. If any changes are made to the INFMYPHEI analysis file during data cleaning, please recreate an updated TNMYPHEI file prior to running this code. The files should be in CSV format. \*/

/\*Please see accompanying readme file. \*/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

**/\*INSTRUCTIONS – complete tasks 1-4 in this section, and run these SAS codes before proceeding to the HEI-2010 scoring program that follows\*/**

/\*1. Create a folder on your computer “home folder”, and save the ASA24 data, and the required HEI-2010 macros in it. Specify the path to the folder. \*/

%let home = C:\Users\Documents\ASA24; /\*In this Example, the “home” folder is in C Drive, within Documents, and is called ASA24. \*/

/\*2. Filenames here specifies the input files. \*/

filename inf4 “&home\inf4\inf4.xls”;

filename tn4 “&home\tn4\tn4.xls”; /\*In this Example, the ASA24 Individual Foods data “inf4”, and the Total Foods data “tn4”, are in folders called “inf4” and “tn4”, all saved within the “home” folder. The data are in Excel format. \*/

/\*3. Create a folder in the "home" folder, where the output file, containing HEI-2010 component and total scores for each respondent, for the intake day, are to be exported. Specify the name of the folder. \*/

filename res “&home\res”; /\*In this Example, the folder is called “RES”, within the “home” folder, and the exported results will be a csv file called “hei2010r”. \*/

/\*4. Read in required HEI-2010 scoring macros. These macros must be saved within the home folder. \*/

%include “&home\hei2010.beanspeas.allocation.macro.sas”;

%include “&home\hei2010.score.macro.sas”;

/\*NOTE: Once you have completed all the steps above, all you need to do is run the SAS program below. Unless you used different names for your datasets and folders, no other action is required from you. \*/

TITLE 'ASA24-2011-14 HEI-2010 scores - by person per day';

/\*Step 1.

Moves soy beverages out of Soybean Products (M\_SOY) and into Dairy (D\_TOTAL).

This uses the ASA24 INFMYPHEI output file. The adjusted totals are generated for

each day of dietary intake and saved in a temporary SAS dataset.

\*/

\*Input the food data;

**proc** **import** datafile=inf4

out=inf4

dbms=xls

replace;

getnames=yes;

**run**;

**data** food;

set inf4;

\*move soy milk from soy to dairy;

/\*FOODCODE=11310000, MILK, IMITATION, FLUID, SOY BASED (1 cup=244 grams)

FOODCODE=11320000, MILK, SOY, READY-TO-DRINK, NOT BABY (1 cup=245 grams)

FOODCODE=11321000, MILK, SOY, READY-TO-DRINK, NOT BABY'S, CHOCOLATE (1 cup=240 grams)

FOODCODE=11330000, MILK, SOY, DRY, RECONSTITUTED, NOT BABY (1 cup=245 grams) \*/

IF FOODCODE=**11310000** THEN DO;

M\_SOY=**0**;

D\_TOTAL=ROUND(FoodAmt/**244**,**.001**);

END;

ELSE IF FOODCODE=**11320000** THEN DO;

M\_SOY=**0**;

D\_TOTAL=ROUND(FoodAmt/**245**,**.001**);

END;

ELSE IF FOODCODE=**11321000** THEN DO;

M\_SOY=**0**;

D\_TOTAL=ROUND(FoodAmt/**240**,**.001**);

END;

ELSE IF FOODCODE=**11330000** THEN DO;

M\_SOY=**0**;

D\_TOTAL=ROUND(FoodAmt/**245**,**.001**);

END;

**run**;

**proc** **sort** data=food;

by username recallno;

**run**;

**proc** **means** data=food noprint;

by username recallno;

var d\_total m\_soy;

output out=adjsum sum=d\_total\_adj m\_soy\_adj;

**run**;

/\*Step 2.

Merges the TNMYPHEI file with the SAS dataset created in Step 1, creating a file with

adjusted variables for the MPED variables of Total Milk (D\_TOTAL\_ADJ) and Soybean Products (M\_SOY\_ADJ).

\*/

\*Input the day total data;

**proc** **import** datafile=tn4

out=tn4

dbms=xls

replace;

getnames=yes;

**run**;

**proc** **sort** data=tn4;

by username recallno;

**run**;

**data** tn4;

merge tn4 adjsum;

by username recallno;

**run**;

/\*Step 3.

Creates four additional required variables. These variables are: MONOPOLY, ALLMEAT, SEAPLANT, and EMPTYCAL10.

\*/

**DATA** both;

SET tn4;

by username recallno;

MONOPOLY=mfat+pfat;

ALLMEAT=M\_MPF+M\_EGG+M\_NUTSD+m\_soy\_adj;

SEAPLANT=M\_FISH\_HI+M\_FISH\_LO+m\_soy\_adj+M\_NUTSD;

/\*\*Calculate intake of Calories from SoFAAS\*\*/

ADDSUGC=**16**\*ADD\_SUG; /\*calories from added sugars\*/

SOLFATC=DISCFAT\_SOL\***9**; /\*calories from solid fat\*/

maxalcgr=**13**\*(kcal/**1000**); /\*max grams of alcohol based on kcal intake\*/

if ALC <= maxalcgr then EXALCCAL=**0**; /\*consumed less than max\*/

else if ALC > maxalcgr then EXALCCAL=**7**\*(ALC-maxalcgr); /\*get cal from extra alc grams\*/

EMPTYCAL10=ADDSUGC+SOLFATC+EXALCCAL; /\*total empty calories in hei2010 definition\*/

**run**;

/\*Step 4.

Runs the macro to properly allocate the intakes of the MPED variable Legumes (LEGUMES)

to either Total Protein Foods and Seafood and Plant Proteins (ALLMEAT and SEAPLANT)

or Total Vegetables and Greens and Beans (V\_TOTAL and V\_DRKGR). The four resulting

variables from this step, named LEGUME\_ADDED\_V\_TOTAL, LEGUME\_ADDED\_BEANGRN,

LEGUME\_ADDED\_ALLMEAT, and LEGUME\_ADDED\_SEAPLANT are all used in the next step.

\*/

%***LEG2010A*** (indat=both,

kcal=KCAL,

allmeat=allmeat,

seaplant=seaplant,

v\_total=v\_total,

v\_drkgr=v\_drkgr,

legumes=legumes,

outdat=afterleg);

/\*Step 5.

Runs the HEI2010 scoring macro which calculates intake density amounts and HEI scores.

\*/

%***HEI2010*** (indat=afterleg,

kcal=KCAL,

lv\_total=legume\_added\_V\_TOTAL,

lbeangrn=legume\_added\_BEANGRN,

f\_total=f\_total,

wholefrt=wholefrt,

g\_whl=g\_whl,

d\_total=d\_total\_adj,

lallmeat=legume\_added\_ALLMEAT,

lseaplant=legume\_added\_SEAPLANT,

monopoly=monopoly,

sfat=sfat,

sodi=SODI,

G\_NWHL=G\_NWHL,

EMPTYCAL10=EMPTYCAL10,

outdat=hei2010);

**run**;

/\*Step 6.

Displays and saves the results.

\*/

**Data** hei2010r (keep=username recallno kcal HEIX1\_TOTALVEG HEIX2\_GREEN\_AND\_BEAN HEIX3\_TOTALFRUIT

HEIX4\_WHOLEFRUIT HEIX5\_WHOLEGRAIN HEIX6\_TOTALDAIRY HEIX7\_TOTPROT HEIX8\_SEAPLANT\_PROT

HEIX9\_FATTYACID HEIX10\_SODIUM HEIX11\_REFINEDGRAIN HEIX12\_SOFAAS

HEI2010\_TOTAL\_SCORE);

Set hei2010;

**Run**;

**proc** **means** n nmiss min max mean data=hei2010r;

**run**;

**proc** **export** data= hei2010r

file=res

dbms=csv

replace;

**run**;